OPTION DECIMALSEP,"." 
RUNM @shortname(C:\command.com)
wait 1
%W = @winexist(Símbolo de MS-DOS)
window send,%W,mem@cr()
wait 2
%%gs_row = 12
%%gs_col = 41
%%gs_len = 8
%%gs_win = %W
gosub getscreen
window close,%W
info Memoria extendida libre %%gs_output
exit


:getscreen
rem Subroutine that gets a single line string of a DOS screen 
rem INPUT gs_row, gs_col, gs_len, gs_win (DOS window identifier) 
rem OUTPUT gs_output 
rem uses and destroy LIST 9 
window click,%%gs_win,10,10
window send,%%gs_win,em
%%gs_temp_i = 1
if @not(@equal(%%gs_temp_i,%%gs_col))
repeat 
window send,%%gs_win,@key(right)
%%gs_temp_i = @succ(%%gs_temp_i)
until @equal(%%gs_temp_i,%%gs_col)
end
%%gs_temp_i = 1
if @not(@equal(%%gs_temp_i,%%gs_row))
repeat 
window send,%%gs_win,@key(down)
%%gs_temp_i = @succ(%%gs_temp_i)
until @equal(%%gs_temp_i,%%gs_row)
end
%%gs_temp_i = 1
repeat 
window send,%%gs_win,@shift(@key(right))
%%gs_temp_i = @succ(%%gs_temp_i)
until @equal(%%gs_temp_i,%%gs_len)@greater(%%gs_temp_i,%%gs_len)
window click,%%gs_win,10,10
window send,%%gs_win,ec
rem looks like it's needed a litle delay in order 
rem to get the clipboard ready for vds 
wait 0.5
list create,9
list paste,9
%%gs_output = @trim(@item(9))
list close,9
exit