REM    _____________________________________________________
REM   |\___________________________________________________/| 
REM   | |                                                 | |
REM   | | SOURCE TITLE:    Move NOTITLE Window            | |
REM   | | ------------                                    | |
REM   | | SOURCE AUTHOR:   Original source by Tommy Sools | |
REM   | | -------------    Modified by Garrett R. Hylltun | |
REM   | |                  Modified by Tommy Sools        | |
REM   | |                                                 | |
REM   | | DATE:            20 March, 2000                 | |
REM   | | UPDATE:          2 September, 2001              | |
REM   | | ----                                            | |
REM   | | REQUIREMENTS:    VDS 3.x; VDSDLL 2.x            | |
REM   | | ------------                                    | |
REM   | | SOURCE STATUS:   Public Domain                  | |
REM   | | -------------                                   | |
REM   | | SOURCE DESCRIPTION:                             | |
REM   | | ------------------                              | |
REM   | |   This example shows you how to use the VDSDLL  | |
REM   | | to make a NOTITLE window mouse dragable.        | |
REM   | |_________________________________________________| |
REM   |/___________________________________________________\|

  External vdsdll.dll,Public Freeware Key|90257236
  DIALOG CREATE,Move NOTITLE,-1,0,200,100,NOTITLE
  DIALOG ADD,STYLE,STYLE6,Courier New,8,,,
  DIALOG ADD,STYLE,STYLE5,Wingdings,12,,LTBLUE,WHITE
  DIALOG ADD,STYLE,STYLE4,MS Sans Serif,8,B,LTBLUE,WHITE
  DIALOG ADD,STYLE,STYLE3,,6,,SILVER,FOREGROUND
  DIALOG ADD,STYLE,STYLE2,,6,,GRAY,FOREGROUND
  DIALOG ADD,STYLE,STYLE1,,6,,WHITE,FOREGROUND
  DIALOG ADD,TEXT,TEXT1,0,0,199,99,TEXT1,STYLE1
  DIALOG ADD,TEXT,TEXT2,1,1,199,99,TEXT2,STYLE2
  DIALOG ADD,TEXT,TEXT3,1,1,198,98,1
  DIALOG ADD,TEXT,TEXT4,1,1,198,18," .",STYLE4
  DIALOG ADD,TEXT,TEXT5,4,24,89,13,Move NOTITLE,STYLE4
  DIALOG ADD,BUTTON,BUTTON2,2,182,16,16,x
  DIALOG ADD,BUTTON,BUTTON3,106,126,64,24,ok
  DIALOG ADD,PROGRESS,PROGRESS1,20,2,196,2
  DIALOG ADD,TEXT,TEXT6,2,4,,,@chr(56),STYLE5
  DIALOG ADD,EDIT,EDIT1,24,4,192,72,,MULTI,WRAP,STYLE6
REM   --- |-------------------------------------------------| ---
REM   --- |   You need a bmp element like below, but with   | ---
REM   --- | no bmp, and make it CLICKable.                  | ---
REM   --- |-------------------------------------------------| ---
  DIALOG ADD,BITMAP,BITMAP1,2,20,160,16,,CLICK
  DIALOG SET,EDIT1,"Grab the TITLE Bar between the Mouse image and the Exit button, and move this NOTITLE Window."
  DIALOG SHOW
  DIALOG FOCUS,BUTTON3
:EVLOOP
  Wait Event
  %E = @event()
  If %E
    Goto %E
  End
  Goto Evloop
:BITMAP1CLICK
REM   --- |-------------------------------------------------| ---
REM   --- |    This is it here.  All you have to do, is     | ---
REM   --- | copy this below, and change the Window Title to | ---
REM   --- | match that of the Window you are using. no      | ---
REM   --- | other modification is needed.                   | ---
REM   --- |-------------------------------------------------| ---
  if @dll(keyboard,Lbutton)
    %%WinY = @diff(@mousepos(Y),@dlgpos(,T))
    %%WinX = @diff(@mousepos(X),@dlgpos(,L))
    Repeat
      %%WinY2 = @diff(@mousepos(Y),%%WinY)
      %%WinX2 = @diff(@mousepos(X),%%WinX)
      if @greater(0,%%WinY2)
        %%WinY2 = 0
      end
      if @greater(0,%%WinX2)
        %%WinX2 = 0
      end
      dialog setpos,,%%WinY2,%%WinX2
    until @not(@dll(keyboard,Lbutton))
  End
  goto evloop
:BUTTON3BUTTON
:BUTTON2BUTTON
:CLOSE
  Exit